Rivanews Setup - Riva-Keltner, Média Rock [xdecow]

xdecow · study · 58 行 · 点赞 890 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © xdecow
 
// Setup from: Rivadavila S. Malheiros (rivanews)
 
//@version=4
study("Rivanews Setup - Riva-Keltner, Média Rock [xdecow]", shorttitle="Rivanews [xdecow]", overlay=true)
 
riva_length = input(21, title="Riva Keltner Length", type=input.integer, minval=2)
rock_length = input(89, title="Rock 89 Length", type=input.integer, minval=2)
riva_mult = input(0.618, title="Riva Keltner Multiplier", type=input.float, minval=0.1)
rock_mult = input(0.618, title="Rock 89 Multiplier", type=input.float, minval=0.1)
 
getKeltnerChannel(src, length, mult) =>
    mid = ema(src, length)
    range = mult * atr(length)
    up = mid + range
    dwn = mid - range
    [mid, up, dwn]
 
[riva_mid, riva_up, riva_dwn] = getKeltnerChannel(close, riva_length, riva_mult)
[rock_mid, rock_up, rock_dwn] = getKeltnerChannel(close, rock_length, rock_mult)
 
riva_trend = close > riva_up and riva_mid > riva_mid[1] and riva_mid > rock_mid ? 1 :
  close < riva_dwn and riva_mid < riva_mid[1] and riva_mid < rock_mid ? -1 : 0
 
// riva keltner
riva_color = riva_trend == 1 ? color.green : riva_trend == -1 ? color.red : #fcba03
 
plot(riva_mid, color=color.gray, title="Riva Keltner", linewidth=1, transp=10)
r1 = plot(riva_up, color=riva_color, title="Riva Keltner Upper Band", linewidth=2, transp=10)
r2 = plot(riva_dwn, color=riva_color, title="Riva Keltner Lower Band", linewidth=2, transp=10)
fill(r1, r2, riva_color, title="Riva Keltner Background", transp=100)
 
 
// rock 89
rock_color = close > rock_up and rock_mid > rock_mid[1] and riva_mid > rock_mid ? color.green :
  close < rock_dwn and rock_mid < rock_mid[1] and riva_mid < rock_mid ? color.red : color.yellow
 
 
plot(rock_mid, color=color.black, title="Rock 89", linewidth=1, transp=10)
rr1 = plot(rock_up, color=rock_color, title="Rock 89 Upper Band", linewidth=2, transp=100)
rr2 = plot(rock_dwn, color=rock_color, title="Rock 89 Lower Band", linewidth=2, transp=100)
fill(rr1, rr2, rock_color, title="Rock 89 Background", transp=80)
 
 
// barcolor
color_uptrend         = #76ff03
color_downtrend       = #f50057
color_uptrend2        = #558b2f
color_downtrend2      = #ad1457
color_cons = #fcba03
color_cons2 = #bd8a00
 
cc(c1, c2) => close > open ? c1 : c2
 
riva_barcolor = riva_trend == 1 ? cc(color_uptrend, color_uptrend2) : riva_trend == -1 ? cc(color_downtrend, color_downtrend2) : cc(color_cons, color_cons2)
barcolor(riva_barcolor)

← 返回列表