Stochastic Momentum Index

JacobTyler · study · 28 行 · 点赞 1,809 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=2
study("Stochastic Momentum Index", "SMI", overlay=false)
 
q = input(10, title="%K Length", type=integer)
r = input(3, title="%K Smoothing Length", type=integer)
s = input(3, title="%K Double Smoothing Length", type=integer)
nsig = input(3, title="Signal Length", type=integer)
matype = input("ema", title="Signal MA Type", type=string)  // possible: ema, sma, wma, trima, hma, dema, tema, zlema
overbought = input(40, title="Overbought Level", type=float)
oversold = input(-40, title="Oversold Level", type=float)
 
trima(src, length) => sma(sma(src,length),length)
hma(src, length) => wma(2*wma(src, length/2)-wma(src, length), round(sqrt(length)))
dema(src, length) => 2*ema(src,length) - ema(ema(src,length),length)
tema(src, length) => (3*ema(src,length) - 3*ema(ema(src,length),length)) + ema(ema(ema(src,length),length),length)
zlema(src, length) => ema(src,length) + (ema(src,length) - ema(ema(src,length),length))
 
smi = 100 * ema(ema(close-0.5*(highest(q)+lowest(q)),r),s) / (0.5 * ema(ema(highest(q)-lowest(q),r),s))
sig = matype=="ema" ? ema(smi,nsig) : matype=="sma" ? sma(smi,nsig) : matype=="wma" ? wma(smi,nsig) : matype=="trima" ? trima(smi,nsig) : matype=="hma" ? hma(smi,nsig) : matype=="dema" ? dema(smi,nsig) : matype=="tema" ? tema(smi,nsig) : matype=="zlema" ? zlema(smi,nsig) : ema(smi,nsig)
 
p_smi = plot(smi, title="SMI", color=#FF8000, transp=0)
p_sig = plot(sig, title="Signal", color=#804000, transp=0)
p_bot = hline(oversold, title="Oversold", color=#00FF00, linestyle=dashed)
p_top = hline(overbought, title="Overbought", color=#FF0000, linestyle=dashed)
fill(p_bot, p_top, title="Middle Region", color=white, transp=85)
fill(p_sig, p_smi, title="SMI/Signal Region", color=smi>sig?green:maroon, transp=50)
fill(plot(oversold,color=lime,editable=false,transp=100), p_smi, title="Oversold Region", color=smi<oversold?#00FF0040:#FFFFFF00)
fill(plot(overbought,color=red,editable=false,transp=100), p_smi, title="Overbought Region", color=smi>overbought?#FF000040:#FFFFFF00)

← 返回列表