Momentum Pressure Index [Trading_Box]

Trading_Box · study · 68 行 · 点赞 191 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=6
indicator("Momentum Pressure Index [Trading_Box]", overlay = false)
 
momentumLength = input.int(14, "Momentum Length", minval = 1)
smoothLength = input.int(5, "Smooth Length", minval = 1)
normalizationLength = input.int(50, "Normalization Length", minval = 10)
 
priceMomentum = ta.roc(close, momentumLength)
 
rsiMomentum = ta.rsi(close, momentumLength) - 50
 
atrValue = ta.atr(14)
atrMomentum = atrValue != 0 ? (close - close[momentumLength]) / atrValue : 0
 
rawPressure = priceMomentum * 0.40 +
              rsiMomentum * 0.35 +
              atrMomentum * 0.25
 
pressure = ta.ema(rawPressure, smoothLength)
 
pressureMean = ta.sma(pressure, normalizationLength)
pressureDev = ta.stdev(pressure, normalizationLength)
 
mpi = pressureDev != 0 ?
      (pressure - pressureMean) / pressureDev :
      0
 
mpi := math.max(-3.0, math.min(3.0, mpi))
 
mpiColor = mpi < 0 ?
     color.from_gradient(mpi, -3, 0, color.red, color.purple) :
     color.from_gradient(mpi, 0, 3, color.purple, color.teal)
 
m = plot(mpi, "MPI", color = mpiColor, linewidth = 2)
 
hline(0, "Zero", color = color.gray)
h = plot(2, "Upper", color = color.new(color.teal, 60))
l = plot(-2, "Lower", color = color.new(color.red, 60))
 
 
buy_signal = ta.crossover(mpi, -2)
sell_signal = ta.crossunder(mpi, 2)
 
 
plotshape(buy_signal, title="", style=shape.triangleup, location=location.bottom, color=color.green, text="", textcolor=color.white, size=size.tiny)
plotshape(sell_signal, title="", style=shape.triangledown, location=location.top, color=color.red, text="", textcolor=color.white, size=size.tiny)
 
//────────────────────────────────────
// FILLS
//────────────────────────────────────
//fill(plot1, plot2, top_value, bottom_value, top_color, bottom_color, title, display, fillgaps, editable) → void
fill(
     m,
     h,
     mpi,
     2,
     color.new(color.red, 80),
     na
)
 
fill(
     m,
     l,
     mpi,
     -2,
     color.new(color.teal, 80),
     na
)

← 返回列表