Double BB, Keltner, EMA100/200, Triple EMA, AutoFib

randomnerd · study · 85 行 · 点赞 515 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=3
study(title="Double BB, Keltner, Triple EMA, AutoFib", shorttitle="2xBB, Keltner, 3xEMA, AutoFib", overlay=true)
 
// inputs
src = input(close, type=source, title="Source")
length = input(20, minval=1, title="BB & Keltner length")
B2mult = input(2.0, minval=0.001, maxval=50, title="Band 1 StDev")
B3mult = input(3.0, minval=0.001, maxval=50, title="Band 2 StDev")
useTrueRange = input(true, title="Use true range for Keltner")
Kmult = input(1.5, title="Keltner Range")
 
//2SD BB
BBbasis = sma(src, length)
B2dev = B2mult * stdev(src, length)
B2upper = BBbasis + B2dev
B2lower = BBbasis - B2dev
 
//3SD BB
B3dev = B3mult * stdev(src, length)
B3upper = BBbasis + B3dev
B3lower = BBbasis - B3dev
 
BBbasisPlot = plot(BBbasis, color=#ff0000, linewidth=2, transp=50, title="BB Basis")
B2upperPlot = plot(B2upper, color=#000080, linewidth=0, transp=70, title="Band 2SD upper")
B2lowerPlot = plot(B2lower, color=#000080, linewidth=0, transp=70, title="Band 2SD lower")
B3upperPlot = plot(B3upper, color=#000080, linewidth=0, transp=70, title="Band 3SD upper")
B3lowerPlot = plot(B3lower, color=#000080, linewidth=0, transp=70, title="Band 3SD lower")
fill(B3upperPlot, B2upperPlot, color=#000080, transp=90, title="BB Background")
fill(B2lowerPlot, B3lowerPlot, color=#000080, transp=90, title="BB Background")
fill(B2upperPlot, B2lowerPlot, color=#000080, transp=95, title="BB Background")
 
//Keltner
Kma = ema(src, length)
Krange = useTrueRange ? tr : high - low
Krangema = ema(Krange, length)
Kupper = Kma + Krangema * Kmult
Klower = Kma - Krangema * Kmult
KupperPlot = plot(Kupper, color=#ff00ff, linewidth=0, transp=70, title="Keltner upper")
KlowerPlot = plot(Klower, color=#ff00ff, linewidth=0, transp=70, title="Keltner lower")
fill(KupperPlot, KlowerPlot, color=#800000, transp=95, title="Keltner Background")
 
// 3xEMA
shortEmaLen = input(15, type=integer, minval=1, title="Short EMA length")
mediumEmaLen = input(20, type=integer, minval=1, title="Medium EMA length")
longEmaLen = input(30, type=integer, minval=1, title="Long EMA length")
slowEmaLen = input(50, type=integer, minval=1, title="Slow EMA length")
shortEma = ema(src, shortEmaLen)
mediumEma = ema(src, mediumEmaLen)
longEma = ema(src, longEmaLen)
slowEma = ema(src, slowEmaLen)
shortEmaPlot = plot(shortEma, color=#009900, linewidth=2, title="Short EMA")
mediumEmaPlot = plot(mediumEma, color=#0000ff, linewidth=4, title="Medium EMA")
longEmaPlot = plot(longEma, color=#ff0000, linewidth=2, title="Long EMA")
slowEmaPlot = plot(slowEma, color=#ff0000, linewidth=4, title="Slow EMA")
 
//Inputs,  Fib inputs can be added here incase custom values are needed.  Will add that on next revision
fLen = input(50, title="Fib length")
fOffset = input(2, title="Fib offset")
 
a=(lowest(fLen)+highest(fLen))/2
b=lowest(fLen)
c=highest(fLen)
 
//Fib Cals
fib1 = (((c-b)*.764)+b)
fib2 = (((c-b)*.618)+b)
fib3 = (((c-b)*.500)+b)
fib4 = (((c-b)*.382)+b)
fib5 = (((c-b)*.236)+b)
 
fib1plot = plot(b[fOffset], color=#000000, linewidth=2, style=line, join=true, title="Fib 1")
fib0plot = plot(c[fOffset], color=#000000, linewidth=2, style=line, join=true, title="Fib 0")
fib764plot = plot(fib1[fOffset], color=#404040, linewidth=1, style=circles, join=true, title="Fib .764")
fib618plot = plot(fib2[fOffset], color=#000000, linewidth=2, style=line, join=true, title="Fib .618")
fib500plot = plot(fib3[fOffset], color=#404040, linewidth=1, style=circles, join=true, title="Fib .500")
fib382plot = plot(fib4[fOffset], color=#000000, linewidth=2, style=line, join=true, title="Fib .382")
fib236plot = plot(fib5[fOffset], color=#404040, linewidth=1, style=circles, join=true, title="Fib .236")
 
// trend indicators
plotshape(crossover(shortEma, longEma), color=#00ff00, size=size.small, location=location.belowbar, transp=30, style=shape.triangleup, title="Short/Long uptrend mark")
plotshape(crossover(mediumEma, longEma), color=#00ff00, size=size.normal, location=location.belowbar, transp=30, style=shape.triangleup, title="Medium/Long uptrend mark")
plotshape(crossover(shortEma, slowEma), color=#00ff00, size=size.large, location=location.belowbar, transp=30, style=shape.triangleup, title="Short/Slow uptrend mark")
plotshape(crossover(longEma, shortEma), color=#ff0000, size=size.small, location=location.abovebar, transp=30, style=shape.triangledown, title="Long/Short downtrend mark")
plotshape(crossover(longEma, mediumEma), color=#ff0000, size=size.normal, location=location.abovebar, transp=30, style=shape.triangledown, title="Long/Medium downtrend mark")
plotshape(crossover(slowEma, shortEma), color=#ff0000, size=size.large, location=location.abovebar, transp=30, style=shape.triangledown, title="Slow/Short downtrend mark")

← 返回列表