Custom Date Anchored VWAP & Standard Deviation Bands

ionaryu · study · 64 行 · 点赞 2 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=6
indicator(title="Anchored VWAP", shorttitle="AVWAP", overlay=true, timeframe="", timeframe_gaps=true)
 
grp_anchor = "VWAP Settings"
hideonDWM = input(false, title="Hide VWAP on 1D or Above", group=grp_anchor, display = display.none)
anchor = input.time(timestamp('2024-01-01T09:00:00'), title = 'Start Date', group = grp_anchor, confirm = true)
src = input(title = "Source", defval = hlc3, group=grp_anchor, display = display.none)
offset = input.int(0, title="Offset", group=grp_anchor, display = display.none)
 
BANDS_GROUP = "Bands Settings"
CALC_MODE_TOOLTIP = "Determines the units used to calculate the distance of the bands. When 'Percentage' is selected, a multiplier of 1 means 1%."
calcModeInput = input.string("Standard Deviation", "Bands Calculation Mode", options = ["Standard Deviation", "Percentage"], group = BANDS_GROUP, tooltip = CALC_MODE_TOOLTIP, display = display.none)
showBand_1 = input(true, title = "", group = BANDS_GROUP, inline = "band_1", display = display.none)
bandMult_1 = input.float(1.0, title = "Bands Multiplier #1", group = BANDS_GROUP, inline = "band_1", step = 0.5, minval=0, display = display.none, active = showBand_1)
showBand_2 = input(false, title = "", group = BANDS_GROUP, inline = "band_2", display = display.none)
bandMult_2 = input.float(2.0, title = "Bands Multiplier #2", group = BANDS_GROUP, inline = "band_2", step = 0.5, minval=0, display = display.none, active = showBand_2)
showBand_3 = input(false, title = "", group = BANDS_GROUP, inline = "band_3", display = display.none)
bandMult_3 = input.float(3.0, title = "Bands Multiplier #3", group = BANDS_GROUP, inline = "band_3", step = 0.5, minval=0, display = display.none, active = showBand_3)
 
cumVolume = ta.cum(volume)
if barstate.islast and cumVolume == 0
    runtime.error("No volume is provided by the data vendor.")
 
// 지정한 anchor 시간에 최초 도달하는 봉에서 VWAP 누적 계산을 리셋(시작)
isNewPeriod = time >= anchor and (na(time[1]) or time[1] < anchor)
 
float vwapValue = na
float upperBandValue1 = na
float lowerBandValue1 = na
float upperBandValue2 = na
float lowerBandValue2 = na
float upperBandValue3 = na
float lowerBandValue3 = na
 
if not (hideonDWM and timeframe.isdwm)
    [_vwap, _stdevUpper, _] = ta.vwap(src, isNewPeriod, 1)
    // 지정한 시작 시점(anchor) 이후의 봉에서만 값을 할당하여 그 이전 구간은 차트에 표시하지 않음
    if time >= anchor
        vwapValue := _vwap
        stdevAbs = _stdevUpper - _vwap
        bandBasis = calcModeInput == "Standard Deviation" ? stdevAbs : _vwap * 0.01
        upperBandValue1 := _vwap + bandBasis * bandMult_1
        lowerBandValue1 := _vwap - bandBasis * bandMult_1
        upperBandValue2 := _vwap + bandBasis * bandMult_2
        lowerBandValue2 := _vwap - bandBasis * bandMult_2
        upperBandValue3 := _vwap + bandBasis * bandMult_3
        lowerBandValue3 := _vwap - bandBasis * bandMult_3
 
plot(vwapValue, title = "VWAP", color = #2962FF, offset = offset)
 
displayBand1 = showBand_1 ? display.all : display.none
upperBand_1 = plot(upperBandValue1, title="Upper Band #1", color = color.green, offset = offset, display = displayBand1, editable = showBand_1)
lowerBand_1 = plot(lowerBandValue1, title="Lower Band #1", color = color.green, offset = offset, display = displayBand1, editable = showBand_1)
fill(upperBand_1, lowerBand_1,      title="Bands Fill #1", color = color.new(color.green, 95),   display = displayBand1, editable = showBand_1)
 
displayBand2 = showBand_2 ? display.all : display.none
upperBand_2 = plot(upperBandValue2, title="Upper Band #2", color = color.olive, offset = offset, display = displayBand2, editable = showBand_2)
lowerBand_2 = plot(lowerBandValue2, title="Lower Band #2", color = color.olive, offset = offset, display = displayBand2, editable = showBand_2)
fill(upperBand_2, lowerBand_2,      title="Bands Fill #2", color = color.new(color.olive, 95),   display = displayBand2, editable = showBand_2)
 
displayBand3 = showBand_3 ? display.all : display.none
upperBand_3 = plot(upperBandValue3, title="Upper Band #3", color = color.teal, offset = offset, display = displayBand3, editable = showBand_3)
lowerBand_3 = plot(lowerBandValue3, title="Lower Band #3", color = color.teal, offset = offset, display = displayBand3, editable = showBand_3)
fill(upperBand_3, lowerBand_3,      title="Bands Fill #3", color = color.new(color.teal, 95),   display = displayBand3, editable = showBand_3)

← 返回列表