EMA Fast & Slow Slope

zerosumbot · study · 70 行 · 点赞 8 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=6
indicator("EMA Fast & Slow Slope", shorttitle="EMA Slopes", overlay=false, precision=4)
 
// Inputs
emaLength = input.int(9, "EMA Length", minval=1)
fastLookback = input.int(4, "Fast Lookback", minval=2)
slowLookback = input.int(9, "Slow Lookback", minval=2)
 
// Calculate EMA
emaValue = ta.ema(close, emaLength)
 
// Linear regression slope normalized to percentage per candle
calculateEmaSlope(array<float> values) =>
    int valueCount = array.size(values)
    float result = 0.0
 
    if valueCount >= 2
        float sumX = 0.0
        float sumY = 0.0
        float sumXY = 0.0
        float sumXX = 0.0
        bool validValues = true
 
        for index = 0 to valueCount - 1
            float value = array.get(values, index)
            if na(value)
                validValues := false
            else
                float x = index
                sumX += x
                sumY += value
                sumXY += x * value
                sumXX += x * x
 
        float baseline = array.get(values, valueCount - 1)
        float denominator = valueCount * sumXX - sumX * sumX
 
        if validValues and not na(baseline) and baseline != 0.0 and denominator != 0.0
            float slope = (valueCount * sumXY - sumX * sumY) / denominator
            result := (slope / baseline) * 100.0
 
    result
 
// Create arrays of EMA values
array<float> array1 = array.new_float()
array<float> array2 = array.new_float()
 
float fastSlope = na
float slowSlope = na
 
// Fast lookback: oldest to newest
if bar_index >= fastLookback - 1
    for i = 0 to fastLookback - 1
        array.push(array1, emaValue[fastLookback - 1 - i])
 
    fastSlope := calculateEmaSlope(array1)
 
// Slow lookback: oldest to newest
if bar_index >= slowLookback - 1
    for i = 0 to slowLookback - 1
        array.push(array2, emaValue[slowLookback - 1 - i])
 
    slowSlope := calculateEmaSlope(array2)
 
// Plot slopes
plot(fastSlope, title="Fast Slope (%)", color=color.purple, linewidth=1)
plot(slowSlope, title="Slow Slope (%)", color=color.orange, linewidth=1)
 
// Zero reference line
hline(0, "Zero", color=color.gray, linestyle=hline.style_dashed)

← 返回列表