Opening Range + Full-Day High/Low + Prev Day + Premarket + Breakout Arrows

eguillot · study · 99 行 · 点赞 123 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=5
indicator("Opening Range + Full-Day High/Low + Prev Day Levels", overlay=true)
 
var float orHi = na      // Opening range high
var float orLo = na      // Opening range low
var float dayHi = na     // Full day high
var float dayLo = na     // Full day low
var float prevDayHi = na
var float prevDayLo = na
var int rangeStart = na
var int rangeEnd = na
var int dayID = na
var box currentBox = na
var line[] allLines = array.new_line()
var box[] allBoxes = array.new_box()
 
todayID = year * 10000 + month * 100 + dayofmonth
isNewDay = na(dayID) or todayID != dayID
 
// Session tracking
inOR  = hour == 9 and minute >= 30 and minute < 45
inRTH = hour >= 9 and hour < 16 or (hour == 16 and minute == 0)
isMarketCloseBar = hour == 16 and minute == 0
 
// Reset values on new day, draw previous day lines
if isNewDay
    if not na(prevDayHi) and not na(prevDayLo)
        sessionStart = timestamp("America/New_York", year, month, dayofmonth, 9, 30)
        sessionEnd   = timestamp("America/New_York", year, month, dayofmonth, 16, 0)
        line.new(x1=sessionStart, y1=prevDayHi, x2=sessionEnd, y2=prevDayHi, color=color.new(color.green, 80), style=line.style_solid, xloc=xloc.bar_time)
        line.new(x1=sessionStart, y1=prevDayLo, x2=sessionEnd, y2=prevDayLo, color=color.new(color.red, 80), style=line.style_solid, xloc=xloc.bar_time)
 
    // Reset tracking for today
    dayID := todayID
    orHi := na
    orLo := na
    dayHi := na
    dayLo := na
    rangeStart := na
    rangeEnd := na
 
// Track full RTH high/low
if inRTH
    dayHi := na(dayHi) ? high : math.max(dayHi, high)
    dayLo := na(dayLo) ? low  : math.min(dayLo, low)
 
// Track opening range
if inOR
    orHi := na(orHi) ? high : math.max(orHi, high)
    orLo := na(orLo) ? low  : math.min(orLo, low)
    rangeStart := na(rangeStart) ? time : rangeStart
    rangeEnd := time
 
// Draw 9:30–9:45 range box and lines
justAfterOR = not inOR and inOR[1] and not na(orHi) and not na(orLo)
if justAfterOR
    sessionStart = timestamp("America/New_York", year, month, dayofmonth, 9, 30)
    sessionEnd   = timestamp("America/New_York", year, month, dayofmonth, 16, 0)
 
    currentBox := box.new(left=rangeStart, right=rangeEnd, top=orHi, bottom=orLo, border_color=color.orange, bgcolor=color.new(color.orange, 85), xloc=xloc.bar_time)
    array.push(allBoxes, currentBox)
 
    lineHigh = line.new(x1=sessionStart, y1=orHi, x2=sessionEnd, y2=orHi, color=color.green, style=line.style_solid, xloc=xloc.bar_time)
    lineLow  = line.new(x1=sessionStart, y1=orLo, x2=sessionEnd, y2=orLo, color=color.red, style=line.style_solid, xloc=xloc.bar_time)
    array.push(allLines, lineHigh)
    array.push(allLines, lineLow)
 
// At market close, lock in the day's full high/low
if isMarketCloseBar
    prevDayHi := dayHi
    prevDayLo := dayLo
 
// === Arrow offset in price units (you can adjust this)
arrowOffset = syminfo.mintick * 100  // or just use 0.5, 1.0 etc.
 
// === Breakout Detection with Offset Arrows
var bool bullBreakoutDrawn = false
var bool bearBreakoutDrawn = false
 
if isNewDay
    bullBreakoutDrawn := false
    bearBreakoutDrawn := false
 
isFiveMin = timeframe.isintraday and timeframe.multiplier == 5
isAfterRange = time > rangeEnd and not na(orHi) and not na(orLo)
body = math.abs(close - open)
full = high - low
bodyPct = full != 0 ? body / full : 0
 
strongBull = close > orHi and bodyPct >= 0.6 and isAfterRange and isFiveMin and not bullBreakoutDrawn
strongBear = close < orLo and bodyPct >= 0.6 and isAfterRange and isFiveMin and not bearBreakoutDrawn
 
if strongBull
    label.new(x=bar_index, y=high + arrowOffset, text="↑", style=label.style_label_up, size=size.small, color=color.new(color.green, 0), textcolor=color.white)
    bullBreakoutDrawn := true
 
if strongBear
    label.new(x=bar_index, y=low - arrowOffset, text="↓", style=label.style_label_down, size=size.small, color=color.new(color.red, 0), textcolor=color.white)
    bearBreakoutDrawn := true

← 返回列表