Market Opening & Closing Times (with Holidays!)

be_zha · study · 390 行 · 点赞 2 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=6
indicator("Market Opening & Closing Times", overlay = true, max_lines_count = 500, max_labels_count = 500)
 
// Holiday lists cover Sep 2026 - Dec 2028. Update the Holidays inputs once a year.
 
TZ_NYSE = "America/New_York"
TZ_LSE = "Europe/London"
TZ_ENX = "Europe/Paris"
TZ_TSE = "Asia/Tokyo"
TZ_KRX = "Asia/Seoul"
TZ_HKEX = "Asia/Hong_Kong"
 
LOOKBACK_DAYS = 10
LOOKAHEAD_DAYS = 14
RANGE_BARS = 100
LABEL_STEP = 0.06
// Drawings can't be placed more than 500 bars past the last bar.
MAX_BARS_AHEAD = 480
 
DATES_TIP = "YYYY-MM-DD, separated by commas or new lines. Weekdays only."
TIMES_TIP = "YYYY-MM-DD=HH:MM in exchange time, separated by commas or new lines."
 
showNyseOpen = input.bool(true, "Show NYSE Open", group = "Events")
showNyseClose = input.bool(true, "Show NYSE Close", group = "Events")
showEuropeOpen = input.bool(true, "Show LSE & Euronext Open", group = "Events")
showEuropeClose = input.bool(true, "Show LSE & Euronext Close", group = "Events")
showAsiaOpen = input.bool(true, "Show TSE & KRX Open", group = "Events")
showAsiaClose = input.bool(true, "Show TSE & KRX Close", group = "Events")
showHkOpen = input.bool(true, "Show HKEX Open", group = "Events")
showHkClose = input.bool(true, "Show HKEX Close", group = "Events")
 
showLines = input.bool(true, "Show Lines", group = "Display")
showNames = input.bool(true, "Show Event Name Label", group = "Display")
showTable = input.bool(false, "Show Countdown Table", group = "Display")
tablePosIn = input.string("Top Right", "Table position", options = ["Top Left", "Top Right", "Bottom Left", "Bottom Right"], group = "Display")
histMode = input.string("Last + next", "Events to show", options = ["Next only", "Last + next", "All"], group = "Display",
      tooltip = "All draws every event from the last N days (below). Past events are dotted.")
daysBack = input.int(14, "Days back (All mode)", minval = 1, maxval = 30, group = "Display",
      tooltip = "Max 30 to stay under the 500 line/label limit.")
axisTzIn = input.string("Asia/Tbilisi", "Time-axis timezone", group = "Display",
      tooltip = "IANA name, e.g. America/New_York. Match your chart's time axis. Blank uses the exchange timezone.")
 
nyseColor = input.color(color.blue, "NYSE Color", group = "Colors")
europeColor = input.color(color.orange, "LSE & Euronext Color", group = "Colors")
lseOnlyColor = input.color(color.yellow, "LSE only (Euronext closed)", group = "Colors")
enxOnlyColor = input.color(color.lime, "Euronext only (LSE closed)", group = "Colors")
asiaColor = input.color(color.white, "TSE & KRX Color", group = "Colors")
tseOnlyColor = input.color(color.purple, "TSE only (KRX closed)", group = "Colors")
krxOnlyColor = input.color(color.aqua, "KRX only (TSE closed)", group = "Colors")
hkColor = input.color(color.red, "HKEX Color", group = "Colors")
 
showFlags = input.bool(true, "Show market status flags", group = "Status flags")
openColor = input.color(color.green, "Open", group = "Status flags")
breakColor = input.color(color.orange, "Lunch break", group = "Status flags")
closedColor = input.color(color.gray, "Closed", group = "Status flags")
 
nyseClosedIn = input.text_area(
      "2026-11-26,2026-12-25\n" +
      "2027-01-01,2027-01-18,2027-02-15,2027-03-26,2027-05-31,2027-06-18,2027-07-05,2027-09-06,2027-11-25,2027-12-24\n" +
      "2028-01-17,2028-02-21,2028-04-14,2028-05-29,2028-06-19,2028-07-04,2028-09-04,2028-11-23,2028-12-25",
      "NYSE closed days", group = "Holidays", tooltip = DATES_TIP)
nyseEarlyIn = input.text_area(
      "2026-11-27=13:00,2026-12-24=13:00\n" +
      "2027-11-26=13:00\n" +
      "2028-07-03=13:00,2028-11-24=13:00",
      "NYSE early closes", group = "Holidays", tooltip = TIMES_TIP)
 
lseClosedIn = input.text_area(
      "2026-12-25,2026-12-28\n" +
      "2027-01-01,2027-03-26,2027-03-29,2027-05-03,2027-05-31,2027-08-30,2027-12-27,2027-12-28\n" +
      "2028-01-03,2028-04-14,2028-04-17,2028-05-01,2028-05-29,2028-08-28,2028-12-25,2028-12-26",
      "LSE closed days", group = "Holidays", tooltip = DATES_TIP)
lseEarlyIn = input.text_area(
      "2026-12-24=12:30,2026-12-31=12:30\n" +
      "2027-12-24=12:30,2027-12-31=12:30\n" +
      "2028-12-22=12:30,2028-12-29=12:30",
      "LSE half-days", group = "Holidays", tooltip = TIMES_TIP + " Last trading day before Christmas and of the year.")
 
enxClosedIn = input.text_area(
      "2026-12-25\n" +
      "2027-01-01,2027-03-26,2027-03-29\n" +
      "2028-04-14,2028-04-17,2028-05-01,2028-12-25,2028-12-26",
      "Euronext closed days", group = "Holidays", tooltip = DATES_TIP + " Paris, Amsterdam, Brussels and Lisbon.")
enxEarlyIn = input.text_area(
      "2026-12-24=14:00,2026-12-31=14:00\n" +
      "2027-12-24=14:00,2027-12-31=14:00",
      "Euronext half-days", group = "Holidays", tooltip = TIMES_TIP)
 
tseClosedIn = input.text_area(
      "2026-09-21,2026-09-22,2026-09-23,2026-10-12,2026-11-03,2026-11-23,2026-12-31\n" +
      "2027-01-01,2027-01-11,2027-02-11,2027-02-23,2027-03-22,2027-04-29,2027-05-03,2027-05-04,2027-05-05,2027-07-19,2027-08-11,2027-09-20,2027-09-23,2027-10-11,2027-11-03,2027-11-23,2027-12-31\n" +
      "2028-01-03,2028-01-10,2028-02-11,2028-02-23,2028-03-20,2028-05-03,2028-05-04,2028-05-05,2028-07-17,2028-08-11,2028-09-18,2028-09-22,2028-10-09,2028-11-03,2028-11-23",
      "TSE closed days", group = "Holidays", tooltip = DATES_TIP + " Includes the Dec 31 - Jan 3 closure.")
 
krxClosedIn = input.text_area(
      "2026-09-24,2026-09-25,2026-10-05,2026-10-09,2026-12-25,2026-12-31\n" +
      "2027-01-01,2027-02-08,2027-02-09,2027-03-01,2027-05-03,2027-05-05,2027-05-13,2027-07-19,2027-08-16,2027-09-14,2027-09-15,2027-09-16,2027-10-04,2027-10-11,2027-12-27,2027-12-31\n" +
      "2028-01-26,2028-01-27,2028-01-28,2028-03-01,2028-04-12,2028-05-01,2028-05-02,2028-05-05,2028-06-06,2028-07-17,2028-08-15,2028-10-02,2028-10-03,2028-10-04,2028-10-05,2028-10-09,2028-12-25,2028-12-29",
      "KRX closed days", group = "Holidays", tooltip = DATES_TIP + " Includes the last weekday of each year.")
krxLateOpenIn = input.text_area(
      "2026-11-19=10:00\n" +
      "2027-01-04=10:00,2027-11-18=10:00\n" +
      "2028-01-03=10:00,2028-11-16=10:00",
      "KRX late opens", group = "Holidays", tooltip = TIMES_TIP + " First trading day of the year and CSAT day.")
krxLateCloseIn = input.text_area(
      "2026-11-19=16:30\n" +
      "2027-11-18=16:30\n" +
      "2028-11-16=16:30",
      "KRX late closes", group = "Holidays", tooltip = TIMES_TIP + " CSAT day.")
 
hkClosedIn = input.text_area(
      "2026-10-01,2026-10-19,2026-12-25\n" +
      "2027-01-01,2027-02-08,2027-02-09,2027-03-26,2027-03-29,2027-04-05,2027-05-13,2027-06-09,2027-07-01,2027-09-16,2027-10-01,2027-10-08,2027-12-27\n" +
      "2028-01-26,2028-01-27,2028-01-28,2028-04-04,2028-04-14,2028-04-17,2028-05-01,2028-05-02,2028-05-29,2028-10-02,2028-10-04,2028-10-26,2028-12-25,2028-12-26",
      "HKEX closed days", group = "Holidays", tooltip = DATES_TIP)
hkHalfDayIn = input.text_area(
      "2026-12-24=12:00,2026-12-31=12:00\n" +
      "2027-02-05=12:00,2027-12-24=12:00,2027-12-31=12:00\n" +
      "2028-01-25=12:00",
      "HKEX half-days", group = "Holidays", tooltip = TIMES_TIP)
 
type Venue
    string name
    string tz
    int openAt
    int closeAt
    array<string> closed
    map<string, int> openChanges
    map<string, int> closeChanges
    color soloColor = na
    int breakStart = na
    int breakEnd = na
 
type Event
    int t
    string name
    color col
 
type Track
    array<Event> events
    bool enabled
    string tz
    string tzLabel
    int level
    string tz2 = ""
    string tzLabel2 = ""
 
splitList(string s) =>
    str.split(str.replace_all(str.replace_all(str.replace_all(s, "\r", ""), "\n", ","), " ", ""), ",")
 
parseTimes(string s) =>
    map<string, int> m = map.new<string, int>()
    for item in splitList(s)
        kv = str.split(item, "=")
        if kv.size() == 2
            hm = str.split(kv.get(1), ":")
            if hm.size() == 2
                m.put(kv.get(0), int(str.tonumber(hm.get(0))) * 60 + int(str.tonumber(hm.get(1))))
    m
 
clock(int h, int m) =>
    h * 60 + m
 
var noChanges = map.new<string, int>()
var nyse = Venue.new("NYSE", TZ_NYSE, clock(9, 30), clock(16, 0), splitList(nyseClosedIn), noChanges, parseTimes(nyseEarlyIn))
var lse = Venue.new("LSE", TZ_LSE, clock(8, 0), clock(16, 30), splitList(lseClosedIn), noChanges, parseTimes(lseEarlyIn), lseOnlyColor)
var enx = Venue.new("Euronext", TZ_ENX, clock(9, 0), clock(17, 30), splitList(enxClosedIn), noChanges, parseTimes(enxEarlyIn), enxOnlyColor)
var tse = Venue.new("TSE", TZ_TSE, clock(9, 0), clock(15, 30), splitList(tseClosedIn), noChanges, noChanges, tseOnlyColor, clock(11, 30), clock(12, 30))
var krx = Venue.new("KRX", TZ_KRX, clock(9, 0), clock(15, 30), splitList(krxClosedIn), parseTimes(krxLateOpenIn), parseTimes(krxLateCloseIn), krxOnlyColor)
var hkex = Venue.new("HKEX", TZ_HKEX, clock(9, 30), clock(16, 0), splitList(hkClosedIn), noChanges, parseTimes(hkHalfDayIn),
      breakStart = clock(12, 0), breakEnd = clock(13, 0))
 
// West to east, as on a map.
var venues = array.from(nyse, lse, enx, hkex, krx, tse)
 
isTradingDay(Venue v, string day, int dow) =>
    dow != dayofweek.saturday and dow != dayofweek.sunday and not v.closed.includes(day)
 
openOn(Venue v, string day) =>
    v.openChanges.contains(day) ? v.openChanges.get(day) : v.openAt
 
closeOn(Venue v, string day) =>
    v.closeChanges.contains(day) ? v.closeChanges.get(day) : v.closeAt
 
// Session times from `back` days ago through the next upcoming one, oldest first.
sessionTimes(Venue v, bool opens, int back) =>
    array<int> out = array.new<int>()
    y = year(timenow, v.tz)
    mo = month(timenow, v.tz)
    d = dayofmonth(timenow, v.tz)
    for i = -back to LOOKAHEAD_DAYS
        noon = timestamp(v.tz, y, mo, d + i, 12, 0)
        day = str.format_time(noon, "yyyy-MM-dd", v.tz)
        if isTradingDay(v, day, dayofweek(noon, v.tz))
            mins = opens ? openOn(v, day) : closeOn(v, day)
            t = timestamp(v.tz, y, mo, d + i, math.floor(mins / 60), mins % 60)
            out.push(t)
            if t > timenow
                break
    out
 
marketStatus(Venue v) =>
    day = str.format_time(timenow, "yyyy-MM-dd", v.tz)
    now = clock(hour(timenow, v.tz), minute(timenow, v.tz))
    switch
        not isTradingDay(v, day, dayofweek(timenow, v.tz)) => "closed"
        now < openOn(v, day) or now >= closeOn(v, day) => "closed"
        not na(v.breakStart) and now >= v.breakStart and now < v.breakEnd => "lunch break"
        => "open"
 
toEvents(array<int> times, string name, color col) =>
    array<Event> out = array.new<Event>()
    for t in times
        out.push(Event.new(t, name, col))
    out
 
soloEvent(int t, Venue v, Venue other, array<int> otherTimes, string what, color pairColor) =>
    otherDay = str.format_time(t, "yyyy-MM-dd", other.tz)
    txt = v.name + " " + what
    c = pairColor
    if other.closed.includes(otherDay)
        txt += " (" + other.name + " closed)"
        c := v.soloColor
    else
        for o in otherTimes
            if str.format_time(o, "yyyy-MM-dd", other.tz) == otherDay
                txt += " (" + other.name + " " + str.format_time(o, "HH:mm", other.tz) + ")"
                break
    Event.new(t, txt, c)
 
// Each pair (LSE/Euronext, TSE/KRX) opens and closes at the same instant, so it shares one track.
mergePair(Venue va, array<int> a, Venue vb, array<int> b, string what, color pairColor) =>
    array<Event> out = array.new<Event>()
    i = 0
    j = 0
    while i < a.size() or j < b.size()
        int ta = i < a.size() ? a.get(i) : na
        int tb = j < b.size() ? b.get(j) : na
        Event e = na
        if not na(ta) and ta == tb
            e := Event.new(ta, va.name + " & " + vb.name + " " + what, pairColor)
            i += 1
            j += 1
        else if na(tb) or (not na(ta) and ta < tb)
            e := soloEvent(ta, va, vb, b, what, pairColor)
            i += 1
        else
            e := soloEvent(tb, vb, va, a, what, pairColor)
            j += 1
        out.push(e)
        // The two lists can end on different days when only one exchange is closed.
        if e.t > timenow
            break
    out
 
marketTime(int t, Track tr, string fmt) =>
    s = str.format_time(t, fmt, tr.tz) + " " + tr.tzLabel
    tr.tz2 == "" ? s : s + " / " + str.format_time(t, "HH:mm", tr.tz2) + " " + tr.tzLabel2
 
textColor(color c) =>
    0.299 * color.r(c) + 0.587 * color.g(c) + 0.114 * color.b(c) > 150 ? color.black : color.white
 
countdown(int t) =>
    mins = math.floor((t - timenow) / 60000)
    str.format("{0}h {1}m", math.floor(mins / 60), mins % 60)
 
var int firstBarTime = time
var lines = array.new<line>()
var labels = array.new<label>()
axisTz = axisTzIn == "" ? syminfo.timezone : axisTzIn
top = ta.highest(high, RANGE_BARS)
bottom = ta.lowest(low, RANGE_BARS)
 
tablePos = switch tablePosIn
    "Top Left" => position.top_left
    "Bottom Left" => position.bottom_left
    "Bottom Right" => position.bottom_right
    => position.top_right
// With both shown, the flags go under the countdown in one table: 12 columns fit 4 countdown cells of 3 and 6 flags of 2.
span = showTable and showFlags ? 3 : 1
flagSpan = showTable ? 2 : 1
flagsRow = showTable ? 9 : 0
var table panel = (showTable or showFlags) and timeframe.isintraday ?
      table.new(tablePos, showTable ? 4 * span : venues.size(), flagsRow + (showFlags ? 1 : 0), frame_color = color.gray, frame_width = 1,
      border_color = color.gray, border_width = 1) : na
 
drawEvent(Event e, Track tr) =>
    past = e.t <= timenow
    barsAhead = (e.t - time) / (timeframe.in_seconds() * 1000)
    if e.t >= firstBarTime and (past or barsAhead <= MAX_BARS_AHEAD)
        c = past ? color.new(e.col, 45) : e.col
        txt = textColor(e.col)
        offset = (top - bottom) * LABEL_STEP * tr.level
        if showLines
            lines.push(line.new(e.t, bottom, e.t, top, xloc = xloc.bar_time, extend = extend.both, color = c,
                  style = past ? line.style_dotted : line.style_dashed))
        if showNames
            name = e.name + "\n" + marketTime(e.t, tr, "HH:mm")
            labels.push(label.new(e.t, top - offset, name, xloc = xloc.bar_time, color = c, style = label.style_label_down,
                  textcolor = txt, size = past ? size.small : size.normal))
        axisTime = str.format_time(e.t, "EEE HH:mm", axisTz)
        labels.push(label.new(e.t, bottom + offset, axisTime, xloc = xloc.bar_time, color = c, style = label.style_label_up,
              textcolor = txt, size = past ? size.normal : size.large, text_formatting = text.format_bold))
 
drawTrack(Track tr) =>
    n = tr.events.size()
    if tr.enabled and n > 0
        first = switch histMode
            "Next only" => n - 1
            "Last + next" => math.max(n - 2, 0)
            => 0
        for k = first to n - 1
            drawEvent(tr.events.get(k), tr)
 
tableRow(int row, Track tr) =>
    if tr.enabled and tr.events.size() > 0
        e = tr.events.last()
        txt = textColor(e.col)
        bg = color.new(e.col, 40)
        panel.cell(0, row, e.name, text_color = txt, bgcolor = e.col, text_halign = text.align_left)
        panel.cell(span, row, marketTime(e.t, tr, "EEE HH:mm"), text_color = txt, bgcolor = bg)
        panel.cell(2 * span, row, str.format_time(e.t, "EEE HH:mm", axisTz), text_color = txt, bgcolor = bg)
        panel.cell(3 * span, row, countdown(e.t), text_color = txt, bgcolor = bg)
    else
        for column = 0 to 3
            panel.cell(column * span, row, "")
 
if barstate.islast and timeframe.isintraday
    for l in lines
        l.delete()
    for lb in labels
        lb.delete()
    lines.clear()
    labels.clear()
 
    back = histMode == "All" ? daysBack : LOOKBACK_DAYS
    nyseOpen = sessionTimes(nyse, true, back)
    nyseClose = sessionTimes(nyse, false, back)
    lseOpen = sessionTimes(lse, true, back)
    lseClose = sessionTimes(lse, false, back)
    enxOpen = sessionTimes(enx, true, back)
    enxClose = sessionTimes(enx, false, back)
    tseOpen = sessionTimes(tse, true, back)
    tseClose = sessionTimes(tse, false, back)
    krxOpen = sessionTimes(krx, true, back)
    krxClose = sessionTimes(krx, false, back)
    hkOpen = sessionTimes(hkex, true, back)
    hkClose = sessionTimes(hkex, false, back)
 
    europeOpen = mergePair(lse, lseOpen, enx, enxOpen, "Open", europeColor)
    europeClose = mergePair(lse, lseClose, enx, enxClose, "Close", europeColor)
    asiaOpen = mergePair(tse, tseOpen, krx, krxOpen, "Open", asiaColor)
    asiaClose = mergePair(tse, tseClose, krx, krxClose, "Close", asiaColor)
 
    tracks = array.new<Track>()
    tracks.push(Track.new(toEvents(nyseOpen, "NYSE Open", nyseColor), showNyseOpen, TZ_NYSE, "ET", 0))
    tracks.push(Track.new(toEvents(nyseClose, "NYSE Close", nyseColor), showNyseClose, TZ_NYSE, "ET", 0))
    tracks.push(Track.new(europeOpen, showEuropeOpen, TZ_LSE, "UK", 1, TZ_ENX, "CET"))
    tracks.push(Track.new(europeClose, showEuropeClose, TZ_LSE, "UK", 1, TZ_ENX, "CET"))
    tracks.push(Track.new(asiaOpen, showAsiaOpen, TZ_TSE, "JST/KST", 2))
    tracks.push(Track.new(asiaClose, showAsiaClose, TZ_TSE, "JST/KST", 2))
    tracks.push(Track.new(toEvents(hkOpen, "HKEX Open", hkColor), showHkOpen, TZ_HKEX, "HKT", 3))
    tracks.push(Track.new(toEvents(hkClose, "HKEX Close", hkColor), showHkClose, TZ_HKEX, "HKT", 3))
 
    if showTable
        panel.cell(0, 0, "Next event", text_color = color.white, bgcolor = color.gray, text_halign = text.align_left)
        panel.cell(span, 0, "Market time", text_color = color.white, bgcolor = color.gray)
        panel.cell(2 * span, 0, "Axis time", text_color = color.white, bgcolor = color.gray)
        panel.cell(3 * span, 0, "In", text_color = color.white, bgcolor = color.gray)
 
    for [i, tr] in tracks
        drawTrack(tr)
        if showTable
            tableRow(i + 1, tr)
 
    if showFlags
        for [i, v] in venues
            state = marketStatus(v)
            c = switch state
                "open" => openColor
                "lunch break" => breakColor
                => closedColor
            panel.cell(i * flagSpan, flagsRow, v.name, text_color = textColor(c), bgcolor = c, tooltip = v.name + " is " + state)
 
    if span > 1
        for row = 0 to flagsRow - 1
            for k = 0 to 3
                panel.merge_cells(k * span, row, k * span + span - 1, row)
        for i = 0 to venues.size() - 1
            panel.merge_cells(i * flagSpan, flagsRow, i * flagSpan + flagSpan - 1, flagsRow)

← 返回列表