EMA RMSD Bands [NJ]

NJ_Algo · study · 91 行 · 点赞 333 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © NJ_Algo
 
//@version=6
indicator("EMA RMSD Bands [NJ]", "ERB", overlay = true, behind_chart = false)
 
//  ███╗   ██╗     ██╗      █████╗ ██╗      ██████╗  ██████╗ 
//  ████╗  ██║     ██║     ██╔══██╗██║     ██╔════╝ ██╔═══██╗
//  ██╔██╗ ██║     ██║     ███████║██║     ██║  ███╗██║   ██║
//  ██║╚██╗██║     ██║     ██╔══██║██║     ██║   ██║██║   ██║
//  ██║ ╚████║ ██╗ ██║     ██║  ██║██║     ██║   ██║██║   ██║
//  ██║  ╚███║ ╚████╔╝     ██║  ██║███████╗╚██████╔╝╚██████╔╝
//  ╚═╝   ╚══╝  ╚═══╝      ╚═╝  ╚═╝╚══════╝ ╚═════╝  ╚═════╝
 
// ✧═════════════════✧
// ║      INPUTS      ║
// ✧═════════════════✧
 
const string g1 = "✧ DISPLAY ✧"
colorMode   = input.string("Colored", "Color mode", options = ["Colored", "Neutral"], group = g1)
dispCandles = input.bool(true, "Color candles", group = g1)
 
const string g2 = "✧ CALCULATION ✧"
rmsdLen   = input.int(28, "RMSD length", group = g2)
rmsdMulti = input.float(1.0, "RMSD multiplier", step = 0.05, group = g2)
 
// ✧══════════════════════✧
// ║      CALCULATION      ║
// ✧══════════════════════✧
 
// Variables
ema = ta.ema(close, rmsdLen)
float rmsdSum = 0
 
// RMSD
for i = 0 to rmsdLen - 1
    rmsdSum += math.pow(close[i] - ema[i], 2)
 
rmsd = math.sqrt(rmsdSum / rmsdLen)
 
// Bands
upperBand = ema + rmsd * rmsdMulti
lowerBand = ema - rmsd * rmsdMulti
 
// ✧═══════════════════════✧
// ║      FINAL SIGNAL      ║
// ✧═══════════════════════✧
 
var int NJ = 0
 
if close > upperBand
    NJ := 1
else if close < lowerBand
    NJ := -1
 
// ✧════════════════✧
// ║      PLOTS      ║
// ✧════════════════✧
 
// Colors
longCol  = colorMode == "Colored" ? color.rgb(0, 136, 100) : colorMode == "Neutral" ? color.rgb(179, 179, 179) : na
shortCol = colorMode == "Colored" ? color.rgb(120, 0, 32) : colorMode == "Neutral" ? color.rgb(60, 60, 60) : na
sigCol = NJ == 1 ? longCol : NJ == -1 ? shortCol : na
 
// Color candles
plotcandle(
     open, high, low, close,
     "Colored candles", 
     dispCandles ? sigCol : na,
     dispCandles ? sigCol : na,
     bordercolor = dispCandles ? sigCol : na,
     display = display.all - display.status_line - display.price_scale)
 
// Display bands and EMA
plot(NJ == -1 ? upperBand : na, "Upper band", shortCol, 2, plot.style_linebr)
plot(NJ == 1  ? lowerBand : na, "Lower band", longCol, 2, plot.style_linebr)
plot(ema, "EMA", color.new(sigCol, 40))
 
// Glow
sma = ta.sma(close, 10)
 
upperCol = NJ == 1 ? color.new(color.black, 100) : color.new(shortCol, 40)
lowerCol = NJ == 1 ? color.new(longCol, 40) : color.new(color.black, 100)
 
upper = NJ == 1 ? sma : upperBand
lower = NJ == 1 ? lowerBand : sma
 
upperPlot = plot(NJ == 1 ? sma : upperBand, "Upper glow", color = na)
lowerPlot = plot(NJ == 1 ? lowerBand : sma, "Lower glow", color = na)
 
fill(upperPlot, lowerPlot, upper, lower, upperCol, lowerCol)

← 返回列表