Ehlers 2-Pole Super Smoother Filter (SSF2)

mihakralj · study · 44 行 · 点赞 10 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// Licensed under the Apache License, Version 2.0
// © mihakralj
//@version=6
// Indicator algorithm (C) 2004-2024 John F. Ehlers
indicator("Ehlers 2-Pole Super Smoother Filter (SSF2)", "SSF2", overlay=true)
 
//@function Calculates 2-pole Supersmooth Lowpass Filter
//@param source Series to calculate SSF2 from
//@param length Number of bars used in the calculation
//@returns SSF2 value with optimized smoothing
//@optimized Uses 2-pole IIR Butterworth-style filter with O(1) complexity per bar
ssf2(series float src, simple int length) =>
    var float SQRT2_PI = math.sqrt(2.0) * math.pi
    var float ssf_internal = 0.0
    var float c1 = 0.0
    var float c2 = 0.0
    var float c3 = 0.0
    var int prev_length = 0
    if prev_length != length
        float arg = SQRT2_PI / float(length)
        float exp_arg = math.exp(-arg)
        c2 := 2.0 * exp_arg * math.cos(arg)
        c3 := -exp_arg * exp_arg
        c1 := 1.0 - c2 - c3
        prev_length := length
    float ssrc = nz(src, src[1])
    float src1 = nz(src[1], ssrc)
    float src2 = nz(src[2], src1)
    ssf_internal := c1 * (ssrc + src1) * 0.5 + c2 * nz(ssf_internal[1], src1) + c3 * nz(ssf_internal[2], src2)
    ssf_internal
 
 
 
// ---------- Main loop ----------
 
// Inputs
i_length = input.int(10, "Length", minval=1)
i_source = input.source(close, "Source")
 
// Calculation
ssf2_val = ssf2(i_source, i_length)
 
// Plot
plot(ssf2_val, "SSF2", color=color.yellow, linewidth=2)

← 返回列表