Squeeze Momentum Indicator [SeaSide420]

SeaSide420 · study · 34 行 · 点赞 2,051 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// @version=4
// @author LazyBear - List of all my indicators: https://www.tradingview.com/v/4IneGo8h/
// @contributor SeaSide420 - List of all my indicators: https://www.tradingview.com/u/SeaSide420/#published-scripts
study(shorttitle="SQZMOM_HMA", title="Squeeze Momentum Indicator [SeaSide420]", overlay=false)
length = input(20, title="BB Length")
mult = input(2.0, title="BB MultFactor")
length2 = input(20, title="HMA Length")
source = input(open, title="Source")
lengthKC = input(20, title="KC Length")
multKC = input(1.5, title="KC MultFactor")
useTrueRange = input(true, title="Use TrueRange (KC)", type=input.bool)
// Calculate HMA
hullma = wma(2 * wma(source, length / 2) - wma(source, length), round(sqrt(length)))
// Calculate BB
basis = hullma
dev = mult * stdev(source, length)
upperBB = basis + dev
lowerBB = basis - dev
// Calculate KC
range = useTrueRange ? tr : high - low
rangema = wma(2 * wma(range, lengthKC / 2) - wma(range, lengthKC), round(sqrt(lengthKC)))
upperKC = hullma + rangema * multKC
lowerKC = hullma - rangema * multKC
 
sqzOn = lowerBB > lowerKC and upperBB < upperKC
sqzOff = lowerBB < lowerKC and upperBB > upperKC
noSqz = sqzOn == false and sqzOff == false
 
val = linreg(source - avg(avg(highest(high, lengthKC), lowest(low, lengthKC)), sma(close, lengthKC)), lengthKC, 0)
 
bcolor = iff(val > 0, iff(val > nz(val[1]), color.lime, color.green), iff(val < nz(val[1]), color.red, color.maroon))
scolor = noSqz ? color.blue : sqzOn ? color.black : color.gray
plot(val, color=bcolor, style=plot.style_histogram, linewidth=4)
plot(0, color=scolor, style=plot.style_cross, linewidth=2)

← 返回列表