Volatility Reversal Bands [Trading_Box]

Trading_Box · study · 79 行 · 点赞 108 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=6
indicator("Volatility Reversal Bands", overlay=true, max_labels_count=500)
 
groupTrend = "Trend System"
groupBands = "Reversal Bands"
groupVisual = "Visual Settings"
groupSignals = "Reversal Signals"
 
trendLength = input.int(34, "Trend Length", minval=1, group=groupTrend)
trendMaType = input.string("SMA", "Trend MA Type", options=["SMA", "EMA", "SMMA (RMA)", "WMA", "VWMA"], group=groupTrend)
trendSource = input.source(close, "Trend Source", group=groupTrend)
trendSmoothLength = input.int(14, "Trend Smoothing", minval=1, group=groupTrend)
trendThreshold = input.float(1.0, "Trend Threshold", minval=0.0, step=0.1, group=groupTrend)
 
bandSensitivity = input.float(3.0, "Band Sensitivity", minval=0.001, maxval=50, step=0.1, group=groupBands)
bandAtrLength = input.int(30, "ATR Expansion Length", minval=1, group=groupBands)
bandAtrMultiplier = input.float(0.8, "ATR Expansion Multiplier", minval=0.0, step=0.1, group=groupBands)
 
bullColor = input.color(color.teal, "Bullish Color", group=groupVisual)
bearColor = input.color(color.red, "Bearish Color", group=groupVisual)
showBands = input.bool(true, "Show Reversal Bands", group=groupVisual)
showBarColors = input.bool(true, "Color Price Bars", group=groupVisual)
 
showSignals = input.bool(true, "Show Reversal Signals", group=groupSignals)
showBullishSignal = input.bool(true, "Show Bullish Signals", group=groupSignals)
showBearishSignal = input.bool(true, "Show Bearish Signals", group=groupSignals)
 
 
getMovingAverage(source, length, maType) =>
    switch maType
        "SMA" => ta.sma(source, length)
        "EMA" => ta.ema(source, length)
        "SMMA (RMA)" => ta.rma(source, length)
        "WMA" => ta.wma(source, length)
        "VWMA" => ta.vwma(source, length)
 
baseMovingAverage = getMovingAverage(trendSource, trendLength, trendMaType)
trendBasis = ta.ema(baseMovingAverage, trendSmoothLength)
 
bandDeviation = bandSensitivity * ta.stdev(trendSource, trendLength)
upperBand = ta.ema(trendBasis + bandDeviation, trendSmoothLength)
lowerBand = ta.ema(trendBasis - bandDeviation, trendSmoothLength)
atrExpansion = ta.atr(bandAtrLength) * bandAtrMultiplier
upperBandOuter = upperBand + atrExpansion
lowerBandOuter = lowerBand - atrExpansion
upperBandExtreme = upperBandOuter + atrExpansion
lowerBandExtreme = lowerBandOuter - atrExpansion
 
trendAtr = ta.atr(14)
trendStrength = trendAtr != 0 ? (trendBasis - trendBasis[1]) / (0.1 * trendAtr) : 0.0
isBearishTrend = trendStrength < -trendThreshold
isBullishTrend = trendStrength > trendThreshold
isNeutralTrend = not isBullishTrend and not isBearishTrend
 
trendColor = color.from_gradient(trendStrength, -trendThreshold, trendThreshold, bearColor, bullColor)
 
plot(trendBasis, "Trend Basis", color=trendColor, linewidth=2)
upperPlot = plot(showBands ? upperBand : na, "Upper Reversal Band", color=color.new(bearColor, 75))
lowerPlot = plot(showBands ? lowerBand : na, "Lower Reversal Band", color=color.new(bullColor, 75))
upperOuterPlot = plot(showBands ? upperBandOuter : na, "Upper Expansion Band", color=color.new(bearColor, 60))
lowerOuterPlot = plot(showBands ? lowerBandOuter : na, "Lower Expansion Band", color=color.new(bullColor, 60))
upperExtremePlot = plot(showBands ? upperBandExtreme : na, "Upper Extreme Band", color=color.new(bearColor, 0))
lowerExtremePlot = plot(showBands ? lowerBandExtreme : na, "Lower Extreme Band", color=color.new(bullColor, 0))
 
fill(upperPlot, upperOuterPlot, color=color.new(bearColor, 90), title="Upper Inner Zone")
fill(lowerPlot, lowerOuterPlot, color=color.new(bullColor, 90), title="Lower Inner Zone")
fill(upperOuterPlot, upperExtremePlot, color=color.new(bearColor, 80), title="Upper Outer Zone")
fill(lowerOuterPlot, lowerExtremePlot, color=color.new(bullColor, 80), title="Lower Outer Zone")
 
bearishReversal = high[1] > upperBand[1] and close[1] > open[1] and close < open
bullishReversal = low[1] < lowerBand[1] and close[1] < open[1] and close > open
 
plotshape(showSignals and showBearishSignal and bearishReversal, "Bearish Reversal", shape.triangledown, location.abovebar, bearColor, size=size.tiny, editable=false)
plotshape(showSignals and showBullishSignal and bullishReversal, "Bullish Reversal", shape.triangleup, location.belowbar, bullColor, size=size.tiny, editable=false)
 
barcolor(showBarColors ? trendColor : na)
 
alertcondition(bullishReversal, "Bullish Reversal", "TrendFlow: Bullish reversal detected.")
alertcondition(bearishReversal, "Bearish Reversal", "TrendFlow: Bearish reversal detected.")

← 返回列表