Jurik Relative Strength Quality Index (RSX)

mihakralj · study · 90 行 · 点赞 11 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// Licensed under the Apache License, Version 2.0
// © mihakralj
//@version=6
indicator("Jurik Relative Strength Quality Index (RSX)", "RSX", overlay=false)
 
//@function Applies three generalized-DEMA stages to momentum and absolute momentum
//@param src Source series
//@param len Filter length
//@returns Clone-style RSX using available filter state during warmup
rsx(series float src, simple int len) =>
    if len <= 0
        runtime.error("Length must be greater than 0")
 
    simple float alpha = 3.0 / (len + 2.0)
    simple float decay = 1.0 - alpha
    simple int warmup = math.max(len - 1, 5)
 
    var float previousScaledPrice = 0.0
    var float momentumStage1Fast = 0.0
    var float momentumStage1Slow = 0.0
    var float momentumStage2Fast = 0.0
    var float momentumStage2Slow = 0.0
    var float momentumStage3Fast = 0.0
    var float momentumStage3Slow = 0.0
    var float magnitudeStage1Fast = 0.0
    var float magnitudeStage1Slow = 0.0
    var float magnitudeStage2Fast = 0.0
    var float magnitudeStage2Slow = 0.0
    var float magnitudeStage3Fast = 0.0
    var float magnitudeStage3Slow = 0.0
    var int warmupCounter = 0
    var bool priceChangedDuringWarmup = false
    var float lastValid = na
 
    float price = na(src) ? lastValid : src
    float result = na
    if not na(price)
        if not na(src)
            lastValid := src
        float smoothedMomentum = 0.0
        float smoothedMomentumMagnitude = 0.0
 
        if warmupCounter == 0
            warmupCounter := 1
            priceChangedDuringWarmup := false
            previousScaledPrice := 100.0 * price
        else
            warmupCounter := warmupCounter >= warmup ? warmup + 1 : warmupCounter + 1
            float priorScaledPrice = previousScaledPrice
            previousScaledPrice := 100.0 * price
            float scaledMomentum = previousScaledPrice - priorScaledPrice
 
            momentumStage1Fast := decay * momentumStage1Fast + alpha * scaledMomentum
            momentumStage1Slow := alpha * momentumStage1Fast + decay * momentumStage1Slow
            float momentumStage1Output = 1.5 * momentumStage1Fast - 0.5 * momentumStage1Slow
            momentumStage2Fast := decay * momentumStage2Fast + alpha * momentumStage1Output
            momentumStage2Slow := alpha * momentumStage2Fast + decay * momentumStage2Slow
            float momentumStage2Output = 1.5 * momentumStage2Fast - 0.5 * momentumStage2Slow
            momentumStage3Fast := decay * momentumStage3Fast + alpha * momentumStage2Output
            momentumStage3Slow := alpha * momentumStage3Fast + decay * momentumStage3Slow
            smoothedMomentum := 1.5 * momentumStage3Fast - 0.5 * momentumStage3Slow
 
            magnitudeStage1Fast := decay * magnitudeStage1Fast + alpha * math.abs(scaledMomentum)
            magnitudeStage1Slow := alpha * magnitudeStage1Fast + decay * magnitudeStage1Slow
            float magnitudeStage1Output = 1.5 * magnitudeStage1Fast - 0.5 * magnitudeStage1Slow
            magnitudeStage2Fast := decay * magnitudeStage2Fast + alpha * magnitudeStage1Output
            magnitudeStage2Slow := alpha * magnitudeStage2Fast + decay * magnitudeStage2Slow
            float magnitudeStage2Output = 1.5 * magnitudeStage2Fast - 0.5 * magnitudeStage2Slow
            magnitudeStage3Fast := decay * magnitudeStage3Fast + alpha * magnitudeStage2Output
            magnitudeStage3Slow := alpha * magnitudeStage3Fast + decay * magnitudeStage3Slow
            smoothedMomentumMagnitude := 1.5 * magnitudeStage3Fast - 0.5 * magnitudeStage3Slow
 
            if warmupCounter <= warmup and previousScaledPrice != priorScaledPrice
                priceChangedDuringWarmup := true
            if warmupCounter == warmup and not priceChangedDuringWarmup
                warmupCounter := 0
 
        if smoothedMomentumMagnitude > 1e-10
            result := math.min(math.max((smoothedMomentum / smoothedMomentumMagnitude + 1.0) * 50.0, 0.0), 100.0)
        else
            result := 50.0
    result
 
// ---------- Main loop ----------
 
i_length = input.int(14, "Length", minval=1)
i_source = input.source(close, "Source")
 
rsx_value = rsx(i_source, i_length)
plot(rsx_value, "RSX", color=color.yellow, linewidth=2)

← 返回列表