Trimmed Mean ATR Bands [NJ]

CryptoNejc · study · 81 行 · 点赞 239 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © CryptoNejc
 
//@version=6
indicator("Trimmed Mean ATR Bands [NJ]", "TMAB", overlay = true, behind_chart = false)
 
// ✧═════════════════✧
// ║      INPUTS      ║
// ✧═════════════════✧
 
const string g1 = "✧ DISPLAY ✧"
displayColCandles = input.bool(true, "Color candles", group = g1)
displayBands = input.bool(true, "Show bands", group = g1)
 
const string g2 = "✧ CALCULATION ✧"
tmSrc = input.source(close, "TM source", group = g2)
trimPct = input.int(25, "Trim amount (%)", minval = 0, maxval = 49, group = g2)
tmLen = input.int(66, "TM length", minval = 1, group = g2)
atrLen = input.int(18, "ATR length", minval = 1, group = g2)
 
// ✧═══════════════════════✧
// ║      TRIMMED MEAN      ║
// ✧═══════════════════════✧
 
tm(tmSrc, tmLen, trimPct) =>
 
    array<float> srcValues = array.new<float>()
 
    for i = 0 to tmLen - 1
        array.push(srcValues, tmSrc[i])
 
    array.sort(srcValues, order.ascending)
 
    trimCount = math.floor(tmLen * trimPct / 100)
 
    float sum = 0
    int count = 0
    for i = trimCount to tmLen - 1 - trimCount
        sum += array.get(srcValues, i)
        count += 1
 
    sum / count
 
trimmedMean = tm(tmSrc, tmLen, trimPct)
 
// ✧════════════════✧
// ║      BANDS      ║
// ✧════════════════✧
 
atr = ta.atr(atrLen)
 
upperBand = trimmedMean + atr
lowerBand = trimmedMean - atr
 
// ✧═══════════════════════✧
// ║      FINAL SIGNAL      ║
// ✧═══════════════════════✧
 
var int NJ = 0
 
if high > upperBand
    NJ := 1
if low < lowerBand
    NJ := -1
 
// ✧════════════════✧
// ║      PLOTS      ║
// ✧════════════════✧
 
sigCol = NJ == 1 ? color.rgb(0, 136, 100) : NJ == -1 ? color.rgb(120, 0, 32) : na
 
plotcandle(
     open, high, low, close,
     "Colored candles", 
     displayColCandles ? sigCol : na,
     displayColCandles ? sigCol : na,
     bordercolor = displayColCandles ? sigCol : na,
     display = display.all - display.status_line - display.price_scale)
 
plot(NJ == -1 and displayBands ? upperBand : na, "Upper band", color.rgb(120, 0, 32), 2, plot.style_linebr)
plot(NJ == 1 and displayBands ? lowerBand : na, "Lower band", color.rgb(0, 136, 100), 2, plot.style_linebr)

← 返回列表