Turtle soup

mickes · study · 153 行 · 点赞 884 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © mickes
 
//@version=6
indicator("Turtle soup", overlay = true, max_boxes_count = 500, max_labels_count = 500, max_lines_count = 500)
 
import mickes/MarketStructure/24
 
_marketStructureLeftPivotLength = input.int(5, "Pivot", inline = "pivot", group = "Market structure")
_marketStructureRightPivotLength = input.int(5, "", inline = "pivot", group = "Market structure")
_marketStructureShowPivots = input.bool(true, "", tooltip = "Set the left and right pivot lengths for the market structure that decides the trend.", inline = "pivot", group = "Market structure")
 
_pivotLeftLength = input.int(1, "Pivot", inline = "liquidityturtlesoup", group = "Turtle soup liquidity")
_pivotRightLength = input.int(1, "", tooltip = "Set the pivot lengths (right and left) that can be  target for a turtle soup.", inline = "liquidityturtlesoup", group = "Turtle soup liquidity")
_lookback = input.int(5, "Lookback", tooltip = "Set how many pivots back that can be a target for a turtle soup.", group = "Turtle soup liquidity")
_timeframe = input.timeframe("", "Timeframe", tooltip = "The higher timeframe for pivots that can be a target for a turtle soup.", group = "Turtle soup liquidity")
_color = input.color(color.new(color.orange, 70), "Color", group = "Turtle soup liquidity")
_confirmation = input.bool(true, "Confirmation", tooltip = "• ENABLED\nThe turtle soup needs to be followed by a change of character (CHoCH) in the opposite direction.\n\n• DISABLED\nAll potential turtle soups will be shown, even the once with the 'wrong' direction (this is due to how higher timeframe values (pivots in this case) are fethed in Pine Script and that the trend can change during that fetching).", group = "Turtle soup liquidity")
 
_marketStructureFontSize = input.int(7, "Market structure font size", group = "Display")
 
_alertFrequency = input.string(alert.freq_once_per_bar_close, "Frequency", [alert.freq_all, alert.freq_once_per_bar, alert.freq_once_per_bar_close], group = "Alerts")
 
type Settings
    int PivotLeftLenght
    int PivotRightLenght
    int Lookback
    bool Confirmation
    color Color
type TurtleSoup
    line Line
    box Box
    int Start
    int End
 
method VisualizeTurtleSoups(array<MarketStructure.Pivot> pivots, array<TurtleSoup> turtleSoups, Settings settings) =>
    reversedPivots = pivots.copy()
    reversedPivots.reverse()
    for pivot in reversedPivots
        if not pivot.LiquidityBroken
            confirmed = switch pivot.Type
                -1 => low > pivot.Price and low[1] <= pivot.Price // turtle soup confimed
                1 => high < pivot.Price and high[1] >= pivot.Price // turtle soup confimed
            if confirmed
                i = 2
                deepest = switch pivot.Type
                    -1 => low[1]
                    1 => high[1]
                while true
                    price = switch pivot.Type
                        -1 => low[i]
                        1 => high[i]
                    swept = switch pivot.Type
                        -1 => price <= pivot.Price
                        1 => price >= pivot.Price
                    if swept
                        i += 1
                        newDeepest = switch pivot.Type
                            -1 => price < deepest
                            1 => price > deepest
                        if newDeepest
                            deepest := price
                    else
                        break // before liquidity sweep
                if i == 2
                    continue // no turtle soup, regular liquidity sweep
                pivot.LiquidityBroken := true
                start = bar_index - i
                end = bar_index - 1
                boxColor = if settings.Confirmation
                    na
                else
                    settings.Color
                lineColor = if settings.Confirmation
                    na
                else
                    color.new(settings.Color, 0)
                turtleSoup = TurtleSoup.new(
                  line.new(pivot.Time, pivot.Price, time[1], pivot.Price, xloc = xloc.bar_time, color = lineColor, style = line.style_dotted),
                  box.new(bar_index - i, pivot.Price, bar_index - 1, deepest, border_width = 0, bgcolor = boxColor, text = "🐢", text_color = boxColor),//color.new(color.white, 50)),
                  start,
                  end)
                removeTurtleSoupIndices = array.new<int>()
                for [j, previousTurtleSoup] in turtleSoups
                    if previousTurtleSoup.Start >= turtleSoup.Start and previousTurtleSoup.End <= turtleSoup.End
                        removeTurtleSoupIndices.unshift(j)
                for removeTurtleSoupIndex in removeTurtleSoupIndices
                    removeTurtleSoup = turtleSoups.get(removeTurtleSoupIndex)
                    removeTurtleSoup.Box.set_text("")//.delete()
                    if turtleSoup.Start > removeTurtleSoup.Start
                        removeTurtleSoup.Line.set_x2(turtleSoup.Start)
 
                if turtleSoups.size() >= 5
                    turtleSoups.pop()
                turtleSoups.unshift(turtleSoup)
                if not settings.Confirmation
                    alert("Turtle soup (not confirmed)", _alertFrequency)
GetPivots(MarketStructure.Liquidity liquidity, Settings settings) =>
    MarketStructure.Pivot pivotHigh = na
    MarketStructure.Pivot pivotLow = na
    pivotHighPrice = ta.pivothigh(settings.PivotLeftLenght, settings.PivotRightLenght)
    pivotLowPrice = ta.pivotlow(settings.PivotLeftLenght, settings.PivotRightLenght)
    if not na(pivotHighPrice)
        pivotHigh := MarketStructure.Pivot.new(pivotHighPrice, Type = 1, Time = time[settings.PivotRightLenght])
    if not na(pivotLowPrice)
        pivotLow := MarketStructure.Pivot.new(pivotLowPrice, Type = -1, Time = time[settings.PivotRightLenght])
    [pivotHigh, pivotLow]
SetPivots(MarketStructure.Liquidity liquidity, Settings settings, MarketStructure.Pivot pivotHigh, MarketStructure.Pivot pivotLow) =>
    if not na(pivotHigh)
        if liquidity.LiquidityPivotsHigh.size() >= settings.Lookback
            liquidity.LiquidityPivotsHigh.pop()
        liquidity.LiquidityPivotsHigh.unshift(pivotHigh)
    if not na(pivotLow)
        if liquidity.LiquidityPivotsLow.size() >= settings.Lookback
            liquidity.LiquidityPivotsLow.pop()
        liquidity.LiquidityPivotsLow.unshift(pivotLow)
TurtleSoup(MarketStructure.Liquidity liquidity, Settings settings, array<TurtleSoup> bullishTurtleSoups, array<TurtleSoup> bearishTurtleSoups) =>
    if barstate.isconfirmed // only if the bar is closed
        liquidity.LiquidityPivotsHigh.VisualizeTurtleSoups(bearishTurtleSoups, settings)
        liquidity.LiquidityPivotsLow.VisualizeTurtleSoups(bullishTurtleSoups, settings)
method Confirm(array<TurtleSoup> turtleSoups, Settings settings, int previousStructureBreakBarIndex) =>
    for turtleSoup in turtleSoups
        if turtleSoup.End > previousStructureBreakBarIndex
            turtleSoup.Line.set_color(color.new(settings.Color, 0))
            turtleSoup.Box.set_bgcolor(settings.Color)
            turtleSoup.Box.set_text_color(settings.Color)
            alert("Turtle soup (confirmed)", _alertFrequency)
 
var priceAction = MarketStructure.PriceAction.new(Swing = MarketStructure.Structure.new(_marketStructureLeftPivotLength, _marketStructureRightPivotLength, MarketStructure.Type.Swing, 0, -1, false, "", color(na), array.new<box>(), array.new<box>(), array.new<MarketStructure.StructureBreak>(), array.new<MarketStructure.Pivot>(), _marketStructureFontSize, false, false, false))
MarketStructure.Pivot(priceAction.Swing)
if _marketStructureShowPivots
    MarketStructure.PivotLabels(priceAction.Swing)
 
var turtleSoup = MarketStructure.Liquidity.new(array.new<MarketStructure.Pivot>(), array.new<MarketStructure.Pivot>())
var settings = Settings.new(_pivotLeftLength, _pivotRightLength, _lookback, _confirmation, _color)
var bullishTurtleSoups = array.new<TurtleSoup>()
var bearishTurtleSoups = array.new<TurtleSoup>()
 
TurtleSoup(turtleSoup, settings, bullishTurtleSoups, bearishTurtleSoups)
 
changeOfCharacter = MarketStructure.ChangeOfCharacter(priceAction.Swing)
breakOfStructure = MarketStructure.BreakOfStructure(priceAction.Swing)
if settings.Confirmation
    var int previousStructureBreakBarIndex = na
    if changeOfCharacter and not na(previousStructureBreakBarIndex)
        switch priceAction.Swing.Trend
            -1 => bearishTurtleSoups.Confirm(settings, previousStructureBreakBarIndex)
            1 => bullishTurtleSoups.Confirm(settings, previousStructureBreakBarIndex)
    if changeOfCharacter or breakOfStructure
        previousStructureBreakBarIndex := bar_index
 
[pivotHigh, pivotLow] = request.security(syminfo.tickerid, _timeframe, GetPivots(turtleSoup, settings))
SetPivots(turtleSoup, settings, pivotHigh, pivotLow)

← 返回列表