ORG + STD DEV

fytte · study · 106 行 · 点赞 877 · TradingView 原页

本页源码来自 TradingView 公开发布的开源脚本,版权归原作者所有, 请遵循其原始许可(Pine 脚本常见 CC BY-NC-SA / MPL-2.0 / MIT)。 本项目仅用于研究检索与许可范围内的移植。

Pine Script

//@version=5
indicator("ORG + STD DEV", overlay = true, max_lines_count = 500, max_boxes_count = 500, max_labels_count = 500, max_bars_back = 5000)
 
var showBox = input.bool(true, title = "Range box", inline = "style")
var boxColor = input.color(color.new(#5d606b, 88), title = "", inline = "style")
var showMid = input.bool(true, title = "Range midline", inline = "style-2")
var midColor = input.color(color.new(#df2d3b, 25), title = "", inline = "style-2")
var stdlines = str.split(input.string("0.5, 1, 1.5, 2", "Std. dev.", inline = "std"), ",")
var stdColor = input.color(color.new(#000000, 85), title = "", inline = "std")
var showLabels = input.bool(true, "Labels", inline = "std-2")
var labelOffset = input.int(2, "Offset", inline = "std-2")
 
var sess = input.session("1614-0930:1234567", title = "", tooltip = "Range period in specified timezone", inline = "sess")
var sessTZ = input.string("US", title = "", options = ["UTC", "US", "UK"], inline = "sess")
 
isSession(sess, dst) =>
    if dst == "UTC"
        timeframe.isintraday and not na(time(timeframe.period, sess, "UTC"))
    else if dst == "US"
        timeframe.isintraday and not na(time(timeframe.period, sess, "America/New_York"))
    else
        timeframe.isintraday and not na(time(timeframe.period, sess, "Europe/London"))
 
[m1_sess, m1_open, m1_close] = request.security_lower_tf(syminfo.tickerid, '1', [isSession(sess, sessTZ), open, close])
var inSession = false
enteredSession = false
exitedSession = false
var float openPrice = na, var float closePrice = na
idx = 0
while idx < array.size(m1_sess)
    if not array.get(m1_sess, idx)
        if inSession
            exitedSession := true
        inSession := false
    if na(openPrice) and array.get(m1_sess, idx)
        openPrice := array.get(m1_open, idx)
        if not inSession
            enteredSession := true
        inSession := true
    if not na(openPrice) and array.get(m1_sess, idx)
        closePrice := array.get(m1_close, idx)
    idx += 1
 
var float range_high = na
var float range_low = na
var float range_middle = na
var box range_box = na
var line mid_line = na
 
numdevlines = array.size(stdlines)
stddevs = array.new_float(numdevlines)
for dev in stdlines
    devNum = str.tonumber(array.get(str.split(dev, " "), 0))
    if not na(devNum)
        stddevs.shift()
        stddevs.push(devNum)
 
var top_arr = array.new_line(numdevlines)
var bot_arr = array.new_line(numdevlines)
var top_label_arr = array.new_label(numdevlines)
var bot_label_arr = array.new_label(numdevlines)
 
if inSession or exitedSession
    if enteredSession
        if showBox
            range_box := box.new(bar_index, na, na, na, bgcolor = boxColor, border_color = color.new(color.white, 100))
        if showMid
            mid_line := line.new(bar_index, na, na, na, color = midColor, style = line.style_dotted)
        for i = 0 to numdevlines - 1
            array.set(top_label_arr, i, label.new(bar_index, na, na, textcolor = stdColor, style = label.style_none))
            array.set(top_arr, i, line.new(bar_index, na, na, na, color = stdColor, style = line.style_solid))
            array.set(bot_label_arr, i, label.new(bar_index, na, na, textcolor = stdColor, style = label.style_none))
            array.set(bot_arr, i, line.new(bar_index, na, na, na, color = stdColor, style = line.style_solid))
 
    range_high := math.max(openPrice, closePrice)
    range_low := math.min(openPrice, closePrice)
    range_middle := math.avg(range_low, range_high)
    if showBox
        box.set_top(range_box, range_high)
        box.set_rightbottom(range_box, bar_index, range_low)
 
    diff = (range_high - range_low)
 
    if showMid
        line.set_y1(mid_line, range_middle)
        line.set_xy2(mid_line, bar_index, range_middle)
 
    for i = 0 to numdevlines - 1
        dev = array.get(stddevs, i)
        t = array.get(top_arr, i)
        hdev = range_high + diff * dev
        line.set_y1(t, hdev)
        line.set_xy2(t, bar_index, hdev)
        tl = array.get(top_label_arr, i)
        tl.set_xy(bar_index + labelOffset, hdev)
        tl.set_text(str.tostring(dev))
        b = array.get(bot_arr, i)
        ldev = range_low - diff * dev
        line.set_y1(b, ldev)
        line.set_xy2(b, bar_index, ldev)
        bl = array.get(bot_label_arr, i)
        bl.set_xy(bar_index + labelOffset, ldev)
        bl.set_text(str.tostring(-dev))
 
if exitedSession
    openPrice := na

← 返回列表